home *** CD-ROM | disk | FTP | other *** search
/ Amiga Tools 2 / Amiga Tools 2.iso / tex / mf / inputs / modes.mf < prev    next >
Text File  |  1995-03-15  |  39KB  |  1,104 lines
  1. % Compiled 1991 by Karl Berry from modes collected by Doug Henderson,
  2. % Pierre MacKay, and others.  This file is in the public domain.
  3. % 
  4. % Please change the definitions of |localfont|, |screen_cols|, and
  5. % |screen_rows| at the end of file (see explanations below).
  6. % 
  7. % When you make a new |mode_def|, please send it to {\tt
  8. % karl@cs.umb.edu} or {\tt dlatex@cmsa.berkeley.edu}.  Please mention
  9. % what fonts at what sizes you tested it on.  This will help other
  10. % people wondering where particular values came from.  Ideally, you
  11. % would try normal, bold, and italic variants, at sizes around 5$\,$pt,
  12. % 10$\,$pt and 15$\,$pt.
  13. % 
  14. % You can run this file through {\tt mft} to generate a \TeX\
  15. % file, if you like reading typeset output instead of computer screens.
  16. % 
  17. %%% def mode_def
  18. %%% addto font_size coding_scheme font_face_byte landscape landscape_
  19. % 
  20. % @mffile{
  21. %   author = "Pierre MacKay, Doug Henderson, et al."
  22. %   version = "0.7",
  23. %   date = "Tue Jul 23 14:07:37 EDT 1991"
  24. %   filename = "modes.mf",
  25. %   contact = "Karl Berry",
  26. %   email = "karl@cs.umb.edu"
  27. %   address = "135 Center Hill Rd. // Plymouth, MA 02360"
  28. %   checksum = "1103   5359  38973",
  29. %   codetable = "ISO/ASCII",
  30. %   supported = "yes",
  31. %   docstring = "
  32. % 
  33. % This file collects all known \MF\ modes, some of which have not been
  34. % tested.  It also makes definitions to put specials identifying the
  35. % mode in the \MF\ GF output, and to put the coding scheme and other
  36. % so-called Xerox-world information in the TFM output.  Finally, it
  37. % defines some code to handle write-white devices better; this code
  38. % comes into play if a |mode_def| includes the statement
  39. % |mode_write_white_setup_;|.  This only works for those fonts which
  40. % follow Computer Modern's conventions for using |font_setup|.
  41. % 
  42. % This file follows a naming convention that has emerged in the
  43. % discussion of |mode_def|s in {\sl TUGboat}.
  44. % 
  45. % \item{1)} The print engine is identified wherever possible,
  46. %   rather than the printer which incorporates that engine.
  47. % 
  48. % \item{2)} Because |mode_def| names may not contain digits,
  49. %   each digit is spelled out; e.g., {\tt RicohFourZeroEightZero}.
  50. % 
  51. % \item{3)} For historical reasons, some modes have synonyms of all
  52. %   lowercase letters, e.g., `cx' for `CanonCX'.  These abbreviations
  53. %   mostly come from {\tt waits.mf}, a predecessor to this file.
  54. %
  55. % This file is typically loaded when making a \MF\ base; for example,
  56. % the command line {\tt inimf plain input modes} makes a file {\tt
  57. % plain.base} (or {\tt plain.bas}, or something like that) with all the
  58. % modes herein defined (plain itself defines modes called |proof|,
  59. % |smoke|, and |lowres|.)
  60. % 
  61. % A user selects a particular mode when s/he runs \MF, by assigning to
  62. % the variable |mode|.  For example, typing
  63. % {\tt \char`\\mode:=CanonCX; input cmr10}
  64. % sets up values appropriate for the CanonCX engine.
  65. % 
  66. % If no mode is assigned, the default is |proof| mode, as stated in {\sl
  67. % The \MF book}.  This is the cause of the ``{\tt .2602gf}'' files which
  68. % are a periodic question in the \TeX\ community.  The remedy is simply
  69. % to assign a different mode---|localfont|, for example.
  70. % 
  71. % Every site should define the mode |localfont| to be a synonym for the
  72. % mode most commonly used there.  This file defines |localfont| to be
  73. % |CanonCX|.  The values for |screen_rows| and |screen_cols|, which
  74. % determine how big \MF's window for online output is, should perhaps
  75. % also be changed; individual users should definitely change them to
  76. % their own tastes.
  77. % 
  78. % This file defines {\tt ?} to type out a list of all the known
  79. % |mode_def|s (once only).
  80. % 
  81. % A |mode_def| is a \MF\ definition that typically consists of a series
  82. % of assignments to various device-specific variables, either primitive
  83. % or defined in plain.  These variables include the following (page
  84. % numbers refer to {\sl The \MF book\/}:
  85. % 
  86. % |aspect_ratio|: the ratio of the vertical resolution to the horizontal
  87. %   resolution (page 94).
  88. % 
  89. % |blacker|: a correction added to the width of stems and similar
  90. %   features, to account for devices which would otherwise make them too
  91. %   light (page 93).  (Write-white devices are best handled by a more
  92. %   sophisticated method than adding to |blacker|, as explained above.)
  93. % 
  94. % |fillin|: a correction factor for diagonals and other features which
  95. %   would otherwise be ``filled in'' (page 94).  An ideal device would
  96. %   have |fillin=0| (page 94).  Negative values for |fillin| will
  97. %   probably either gross effects or none at all.
  98. % 
  99. % |fontmaking|: if nonzero at the end of the job, \MF\ makes a TFM file
  100. %   (page 315).
  101. % 
  102. % |o_correction|: a correction factor for the ``overshoot'' of curves
  103. %   beyond the baseline (or x-height, or some other line).  High
  104. %   resolution curves look better with overshoot, so such devices should
  105. %   have |o_correction=1|; but at low resolutions, the overshoot appears
  106. %   to simply be a distortion (page 93).  Here some additional comments
  107. %   about |o_correction|, courtesy of Pierre MacKay (edited by Karl):
  108. % 
  109. %   At present, I find that |o_correction| works nicely at 80 pixels per
  110. %   em, and gets increasingly disturbing as you move down towards 50
  111. %   pixels per em. Below that I do not think it ought to happen at all.
  112. %
  113. %   The problem, of course, is that full |o_correction| is supposed to
  114. %   occur only at the zenith and nadir of the curve of `o', which is a
  115. %   small region at high resolution, but may be a long line of
  116. %   horizontal pixels at medium resolution.  The full |o_correction|
  117. %   does not change a 300$\,$dpi {\tt cmr10}, but it changes a 21-pixel
  118. %   high {\tt cmr12} to be 23 pixels high.  The extra height and depth
  119. %   is seen along a line of seven pixels at the bottom and five at the
  120. %   top.  This is a pronounced overshoot indeed.
  121. %
  122. %   For high-resolution devices, such as phototypesetters, the values
  123. %   for |blacker|, |fillin|, and |o_correction| don't matter all that
  124. %   much, so long as the values are within their normal ranges: between
  125. %   0 and 1, with the values approaching 0, 0, and 1 respectively.
  126. % 
  127. % |pixels_per_inch|: the horizontal resolution; the \MF\ primitive
  128. %   |hppp| (which is what determines the extension on the GF filename,
  129. %   as among other things) is computed from this (page 94).
  130. %
  131. %   To be more precise, you can determine the resolution of a font given
  132. %   a |mode_def| and a magnification |m| by simply multiplying
  133. %   |pixels_per_inch| for that |mode_def| by |m|.  (Of course, your
  134. %   results may differ from \MF's if you don't use equivalent
  135. %   fixed-point arithmetic routines.)  Then you can determine the number
  136. %   used in the name of the GF font output by rounding.  For example, a
  137. %   font generated at |magstep(.5)| (which is $\sqrt{1.2}$, which \MF
  138. %   computes as 1.09544) for a printer with |pixels_per_inch=300| will
  139. %   have a resolution of 328.63312 dots per inch, and the GF filename
  140. %   will include the number {\tt 329}.
  141. %
  142. % |proofing|: says whether to put additional specials in the GF file for
  143. %   use in making proofsheets with the assistance of, e.g., the utility
  144. %   program {\tt GFtoDVI} (page 323--4).
  145. % 
  146. % |tracingtitles|: if nonzero, strings that appear as \MF\ statements
  147. %   are typed on the terminal (page 187).
  148. % 
  149. % Neenie Billawala's article in the April 1987 issue of {\sl TUGboat}
  150. % describes how to test your printer for the best set of values for the
  151. % magic numbers above.  Here are some brief comments on the subject,
  152. % courtesy of {\tt rocky@ibm.com}, again edited by Karl:
  153. % 
  154. % For medium-to-low resolution devices, you can first set the |blacker|
  155. % and |o_correction| to~0 and decide on a |fillin| value by looking at
  156. % the diagonal of a lowercase `z' in the typewriter font. The diagonal
  157. % should be the same thickness as the horizontal bars of the `z'. Then I
  158. % decide on the |blacker| value, generally by checking the smaller fonts
  159. % for too much filling in.  Finally, you can set the |o_correction|
  160. % using the guidelines suggested above.
  161. % 
  162. %"
  163. % }
  164.  
  165. % Identify ourselves in the format file.
  166. base_version := base_version & "/modes 0.7";
  167.  
  168.  
  169. % Here are useful macros (also called definitions) that we will use
  170. % throughout.
  171.  
  172. % First, some comments about how the |mode_defs| are constructed (from
  173. % {\tt rocky@ibm.com}).  In the past, |mode_defs| unconditionally
  174. % assigned a value to the various mode-dependent parameters. For
  175. % example, they contained an assignment |fontmaking:=1|, which tells
  176. % \MF\ to write a TFM file.
  177. %
  178. % But suppose you want to generate a font using all of the setup for
  179. % some mode |m|, but just do not want to generate a tfm? One could
  180. % create another mode that doesn't have the assignment, but this seems a
  181. % bit wasteful since the rest of the code in the mode would be
  182. % duplicated.  Furthermore, given the way the mode definitions were
  183. % written, it was not possible to change the mode parameters.  To see
  184. % why, I review how a \MF run typically works.
  185. %
  186. % First, \MF is invoked with some base file to load.  Then you might
  187. % want give additional instructions, such as |scrollmode|, or |mode:=m|.
  188. % Next, you input a parameter file, say {\tt cmr10}.  The parameter file
  189. % calls a driver file, such as {\tt roman}, with the command |generate
  190. % roman|.  Finally, the driver finished by saying |bye| or |end|.  Thus,
  191. % any additional commands you give after the input of the parameter file
  192. % are ignored.
  193. %
  194. % Usually, one of the first things a driver file does is to call
  195. % |mode_setup|. It is here that the mode parameters are set.  (In our
  196. % hypothetical mode, it would be here that |fontmaking| is assigned.)
  197. %
  198. % To allow a flexible setting of |fontmaking|, we can make a simple
  199. % change: in the |mode_def|, first test to see if a value has been
  200. % defined prior and only make the assignment if not. That is:
  201. % |if unknown fontmaking: fontmaking := 1; fi|.
  202. %
  203. % Alas, this doesn't work.  Primitives, like |fontmaking|, are always
  204. % |known|.  So instead we create ``guard'' variables, e.g.,
  205. % |mode_guard_.fontmaking|; we set the guard variable when we assign the
  206. % parameter.  Then we test whether the guard variable is |known| before
  207. % we actually do an assignment.
  208. % This allows more flexible definitions: you can specify some of the
  209. % parameters, and keep the default value for others.
  210. %
  211. % It is also possible to write a program that creates a |mode_def| on
  212. % the fly. Although useful, this has a slightly different focus than
  213. % starting with an existing |mode_def| and changing a couple of
  214. % parameters. In particular, one still has to peek inside the
  215. % file to see what the old values were and set them again (in the
  216. % new context). Also, such on-the-fly |mode_def| generation programs are
  217. % inherently less machine-independent that a scheme that does
  218. % everything in \MF\ itself.
  219. %
  220. % The upshot of all this is the following definition:  we say, e.g.,
  221. % |mode_param (fontmaking, 1)| below, instead of doing a real
  222. % assignment.  The name (``|mode_param|'') is kept short because you
  223. % also use this to override a mode assignment, on the command line or in
  224. % response to the {\tt **} prompt.
  225. def mode_param (suffix v) (expr e) =
  226.   if unknown mode_guard_.v:
  227.     v := e;
  228.     mode_guard_.v := 1;
  229.   fi
  230. enddef;
  231.  
  232. % This macro is invoked by all the modes, after |pixels_per_inch|
  233. % has been defined, thus saving some space and time.
  234. def mode_common_setup_ =
  235.   mode_param (proofing, 0);
  236.   mode_param (fontmaking, 1);
  237.   mode_param (tracingtitles, if pixels_per_inch > 700: 1 else: 0 fi);
  238. enddef;
  239.  
  240.  
  241. % In a similar spirit, here are definitions to change to ``landscape''
  242. % mode.  You just say {\tt mode := whatever; landscape; ...}, and when
  243. % |mode_setup| is executed, the |aspect_ratio| will be inverted, and
  244. % |pixels_per_inch| changed.
  245. def landscape =
  246.   extra_setup := extra_setup & "landscape_;"
  247. enddef;
  248.  
  249. def landscape_ =
  250.   begingroup
  251.     interim warningcheck := 0;
  252.     pixels_per_inch := aspect_ratio * pixels_per_inch;
  253.     aspect_ratio := 1 / aspect_ratio;
  254.   endgroup
  255. enddef;
  256.  
  257.  
  258. % Here are macros to add specials with mode information to the GF file.
  259. % 
  260. % Specifically, we add the |pixels_per_inch|, |o_correction|,
  261. % |aspect_ratio| (if not 1), |mag|, |fillin|, and |mode_def| name.  This
  262. % information can be used to automatically verify that a font file name
  263. % matches the specification within the file.  For example, you could
  264. % check that the number in the filename matches |mag*pixels_per_inch|.
  265. % Or, if the |mode_def| name is is put in the font directory path (e.g.,
  266. % you put fonts in {\tt $\ldots$/tex/fonts/CanonCX}), that all of the
  267. % bitmap files in the directory have the expected |mode_def| name.
  268.  
  269. def mode_special_ (suffix $) =
  270.   string s, d;
  271.   s := str $;
  272.   d := decimal scantokens s;
  273.   special s & " := " & d & ";"
  274. enddef;
  275.  
  276. def mode_output_specials_ =
  277.   begingroup
  278.     save d, s, p, p_p_i;
  279.     string p;
  280.  
  281.     interim warningcheck := 0; % In case |pixels_per_inch>4096|.
  282.  
  283.     % We need the old |pixels_per_inch| to compute the true device
  284.     % resolution.
  285.     p_p_i = pixels_per_inch / mag;
  286.  
  287.     % But now we want to change |pixels_per_inch|, so we |save| the
  288.     % old value.
  289.     save pixels_per_inch;
  290.     pixels_per_inch := p_p_i;
  291.  
  292.     special jobname;
  293.     mode_special_ (mag);
  294.  
  295.     p := if string mode:
  296.            mode
  297.          else:
  298.            substring (0, length (mode_name[mode]) - 1) of mode_name[mode]
  299.          fi;
  300.     special "mode := " & p & ";";
  301.  
  302.     mode_special_ (pixels_per_inch);
  303.     if aspect_ratio <> 1:
  304.       mode_special_ (aspect_ratio);
  305.     fi;
  306.     mode_special_ (blacker);
  307.     mode_special_ (fillin);
  308.     mode_special_ (o_correction);
  309.   endgroup
  310. enddef;
  311.  
  312.  
  313. % Here are macros for Xerox-world font info, which can be useful even
  314. % if you never use a Xerox printer.  For instance, {\tt crudetype} uses
  315. % the |coding_scheme| and it is nice to have the font family on record.
  316. % This goes into both the TFM file (as |headerbyte| information), and
  317. % into the GF file, with |special|.
  318.  
  319. % Make the string |s| be |n| bytes long.
  320. def BCPL_string (expr s, n) =
  321.   for l := if length (s) >= n: n-1 else: length (s) fi: l
  322.     for k := 1 upto l: , substring (k - 1, k) of s endfor
  323.     for k := l + 2 upto n: , 0 endfor
  324.   endfor
  325. enddef;
  326.  
  327. % The string |s| names the encoding scheme, e.g., {\tt TeX TEXT}.
  328. def coding_scheme expr s =
  329.   headerbyte 9: BCPL_string (s, 40);
  330.   special "codingscheme " & s
  331. enddef;
  332.  
  333. % The string |s| names the font family, e.g., {\tt CMR}.
  334. def font_family expr s =
  335.   headerbyte 49: BCPL_string (s, 20);
  336.   special "identifier " & s
  337. enddef;
  338.  
  339. % The integer |x| gives the family member number, which should be
  340. % between 0 and 255.
  341. def font_face_byte expr x =
  342.   headerbyte 72: x;
  343.   special "fontfacebyte";
  344.   numspecial x
  345. enddef;
  346.  
  347. % So users can say |if known Xerox_world: $\ldots$ fi|
  348. Xerox_world := 1;
  349.  
  350.  
  351. % Redefine |end| to put the extra information above in the GF and TFM
  352. % files.  This code is based on that on page 321.
  353. inner end;
  354. let primitive_end_ = end;
  355. def end =
  356.   if fontmaking > 0:
  357.     font_family font_identifier_;
  358.     coding_scheme font_coding_scheme_;
  359.     font_face_byte max (0, 254 - round 2designsize); 
  360.     mode_output_specials_;
  361.   fi;
  362.   primitive_end_.
  363. enddef;
  364.  
  365. % The {\sl \MF book} gives |bye| two different definitions (on pages 278
  366. % and 321). The first is used in {\tt plain.mf} and is merely a synoynym
  367. % for the primitive |end|.  The second, which is not part of {\tt
  368. % plain.mf}, is similar to the code given above. We want the extra
  369. % information to get into the output files regardless of whether the
  370. % \MF\ source used |end| or |bye|.  The above changed |end|; now we have
  371. % to redefine |bye| again (as on page 278).
  372. outer end, primitive_end_;
  373. let bye = end;
  374.  
  375.  
  376. % Here are macros to handle write-white printers.
  377. %
  378. % The basic correction for write-white fonts occurs in the definition of
  379. % |font_setup|.  This can be used to extend or change the write-black
  380. % definition in Computer Modern's {\tt cmbase.mf} or other base files
  381. % based on CM, such as {\tt dxbase.mf}.
  382. %
  383. def mode_write_white_setup_ =
  384.   begingroup
  385.     let black_setup = font_setup;
  386.     def font_setup =
  387.       black_setup;
  388.       min_Vround:=max(fine.breadth,crisp.breadth,tiny.breadth,2);
  389.       if min_Vround<vround min_Vround: min_Vround:=vround min_Vround; fi
  390.       if flare<vround flare: flare:=vround flare; fi
  391.       forsuffixes $=vair,bar,slab,cap_bar,cap_band,vair',vstem,cap_vstem,bold:
  392.         if $<min_Vround: $:=min_Vround; fi endfor
  393.       forsuffixes $=thin_join,hair,curve,flare,dot_size,cap_hair,cap_curve,
  394.        vair,bar,slab,cap_bar,cap_band,stem',cap_stem',vair',fudged.hair,
  395.        fudged.stem,fudged.cap_stem: $:=max($,2); endfor
  396.     enddef;
  397.   endgroup
  398. enddef;
  399.  
  400.  
  401. % Here are the modes, given in alphabetical order (without regard to case).
  402.  
  403. % From {\tt cudat@cu.warwick.ac.uk}.
  404. mode_def AgfaFourZeroZero =             % AGFA 400PS
  405.   mode_param (pixels_per_inch, 406);
  406.   mode_param (blacker, .2);
  407.   mode_param (fillin, 0);
  408.   mode_param (o_correction, .6);
  409.   mode_common_setup_;
  410. enddef;
  411.  
  412. % From {\tt rokicki@neon.stanford.edu}.
  413. mode_def amiga =                        % Commodore Amiga.
  414.   mode_param (pixels_per_inch, 100);
  415.   mode_param (blacker, 0);
  416.   mode_param (fillin, 0);
  417.   mode_param (o_correction, .2);
  418.   mode_common_setup_;
  419. enddef;
  420.  
  421. % From {\tt ee@dacth51.bitnet}.
  422. mode_def AtariSLMEightZeroFour =        % Atari ST SLM 804 printer
  423.   mode_param (pixels_per_inch, 300);
  424.   mode_param (blacker, -.25);
  425.   mode_param (fillin, .5);
  426.   mode_param (o_correction, 0);
  427.   mode_common_setup_;
  428.   mode_write_white_setup_;
  429. enddef;
  430.  
  431. % From {\tt ee@dacth51.bitnet}.
  432. mode_def AtariSMOneTwoFour =            % Atari ST SM 124 screen
  433.   mode_param (pixels_per_inch, 101);
  434.   mode_param (blacker, 0);
  435.   mode_param (fillin, 0);
  436.   mode_param (o_correction, .4);
  437.   mode_common_setup_;
  438. enddef;
  439.  
  440. mode_def aps =                          % Autologic APS-Micro5
  441.   mode_param (pixels_per_inch, 722.909);
  442.   mode_param (blacker, .2);
  443.   mode_param (fillin, .2);
  444.   mode_param (o_correction, 1);
  445.   mode_common_setup_;
  446. enddef;
  447.  
  448. % From {\tt rocky@ibm.com}.  Tested on the single APS-6 at IBM
  449. % Research.
  450. mode_def ApsSixHi =                     % Autologic APS-Micro6
  451.   mode_param (pixels_per_inch, 1016);
  452.   mode_param (blacker, 0);
  453.   mode_param (fillin, 0);
  454.   mode_param (o_correction, 1);
  455.   mode_common_setup_;
  456. enddef;
  457.  
  458. mode_def bitgraph =                     % BBN Bitgraph at 118dpi
  459.   mode_param (pixels_per_inch, 118);
  460.   mode_param (blacker, .55);
  461.   mode_param (fillin, .1);
  462.   mode_param (o_correction, .3);
  463.   mode_common_setup_;
  464. enddef;
  465.  
  466. mode_def boise =                        % HP 2680A
  467.   mode_param (pixels_per_inch, 180);
  468.   mode_param (blacker, .55);
  469.   mode_param (fillin, .1);
  470.   mode_param (o_correction, .3);
  471.   mode_common_setup_;
  472. enddef;
  473.  
  474. % This applies to the LaserWriter Plus, HP Laserjet, HP Laserjet Plus,
  475. % and also the Canon LBP-LX engine, in the Laserjet IIP, QMS 410, and
  476. % Apple Personal LaserWriter.
  477. mode_def CanonCX =                      % e.g., Apple LaserWriter
  478.   mode_param (pixels_per_inch, 300);
  479.   mode_param (blacker, 0);
  480.   mode_param (fillin, .2);
  481.   mode_param (o_correction, .6);
  482.   mode_common_setup_;
  483. enddef;
  484. cx := CanonCX;
  485. corona := CanonCX;
  486. dp := CanonCX; % some kind of DataProducts
  487. imagen := CanonCX;
  488. laserwriter := CanonCX;
  489. % I have seen a |mode_def| that claimed the LaserJet II was the Canon SX
  490. % write-white engine, but I don't think that's right.
  491. laserjethi := CanonCX;
  492. laserjet := CanonCX;
  493.  
  494. mode_def CanonLBPTen =                  % e.g., Symbolics LGP-10
  495.   mode_param (pixels_per_inch, 240);
  496.   mode_param (blacker, .2);
  497.   mode_param (fillin, .2);
  498.   mode_param (o_correction, .4);
  499.   mode_common_setup_;
  500. enddef;
  501.  
  502. mode_def CanonSX =                      % Canon SX
  503.   mode_param (pixels_per_inch, 300);
  504.   mode_param (blacker, .2);
  505.   mode_param (fillin, -.2);
  506.   mode_param (o_correction, .5);
  507.   mode_common_setup_;
  508.   mode_write_white_setup_;
  509. enddef;
  510.  
  511. % The Chelgraph IBX is the machine introduced to North American \TeX\
  512. % users by Type~2000 in Mill Valley, California; telephone
  513. % (415)~388-8873.  Since the machine's stated output resolution is only
  514. % 2000\thinspace dpi this truly spectacular 9600\thinspace dpi must be
  515. % used for translation to an outline font description.  This
  516. % |mode_def| has been tested and used in a publication of the University
  517. % of Washington Press.  These values from Pierre MacKay, based on Lance
  518. % Carnes' crs values, at magstep~1.8.
  519. mode_def ChelgraphIBX =                 % Chelgraph IBX
  520.   mode_param (pixels_per_inch, 4000 + 4000 + 1600);
  521.   mode_param (blacker, 4);
  522.   mode_param (fillin, 0);
  523.   mode_param (o_correction, 1);
  524.   mode_common_setup_;
  525. enddef;
  526.  
  527. % From {\tt rokicki@cs.umb.edu}.
  528. mode_def CItohThreeOneZero =            % CItoh 310
  529.   mode_param (pixels_per_inch, 240);
  530.   mode_param (aspect_ratio, 144 / pixels_per_inch);
  531.   mode_param (blacker, 0);
  532.   mode_param (fillin, 0);
  533.   mode_param (o_correction, .2);
  534.   mode_common_setup_;
  535. enddef;
  536. cthreeten := CItohThreeOneZero;
  537.  
  538. mode_def CompugraphicEightSixZeroZero = % Compugraphic 8600
  539.   mode_param (pixels_per_inch, 1301.5);
  540.   mode_param (aspect_ratio, 1569 / pixels_per_inch);
  541.   mode_param (blacker, .2);
  542.   mode_param (fillin, .2);
  543.   mode_param (o_correction, 1);
  544.   mode_common_setup_;
  545. enddef;
  546. cg := CompugraphicEightSixZeroZero;
  547.  
  548. % This has a resolution of |5333 + 1/3| pixels per inch.
  549. mode_def crs =                          % Alphatype CRS
  550.   mode_param (pixels_per_inch, 4000 + 4000/3);
  551.   mode_param (blacker, 4); 
  552.   mode_param (fillin, 0);
  553.   mode_param (o_correction, 1);
  554.   mode_common_setup_;
  555. enddef;
  556.  
  557. % At least magstep 2 is recommended at this low resolution.
  558. mode_def DataDisc =                     % DataDisc
  559.   mode_param (pixels_per_inch, 70);
  560.   mode_param (blacker, 0);
  561.   mode_param (fillin, 0);
  562.   mode_param (o_correction, .2);
  563.   mode_common_setup_;
  564. enddef;
  565. DD := DataDisc;
  566.  
  567. mode_def DataDiscNew =                  % DataDisc with special aspect ratio
  568.   DataDisc_;
  569.   mode_param (aspect_ratio, 4/3);
  570. enddef;
  571. newDD := DataDiscNew;
  572.  
  573. mode_def dover =                        % Xerox Dover
  574.   mode_param (pixels_per_inch, 384);
  575.   mode_param (blacker, 1.2);
  576.   mode_param (fillin, 0);
  577.   mode_param (o_correction, .6);
  578.   mode_common_setup_;
  579. enddef;
  580.  
  581. % These values from Charles Karney, {\sl TUGboat} 8(2), page 133.  This
  582. % is for the Epson MX/FX family (-85, -286), which are 9-pin printers.
  583. % The 24-pin LQ family have higher resolutions; no one has sent me
  584. % |mode_def|s for them yet.  Ditto for Epson's laser printer.  (Thanks
  585. % to {\tt cargo@escargot.cray.com} for all this information.)
  586. mode_def EpsonMXFX =                    % 9-pin Epson MX/FX family
  587.   mode_param (pixels_per_inch, 240);
  588.   mode_param (aspect_ratio, 216 / pixels_per_inch);
  589.   mode_param (blacker, 0);
  590.   mode_param (fillin, 0);
  591.   mode_param (o_correction, .2);
  592.   mode_common_setup_;
  593. enddef;
  594. epson := EpsonMXFX;
  595. epshi := EpsonMXFX;
  596.  
  597. % Perhaps this should be 120 horizontally and 216 vertically, if it is
  598. % for the MX-80.  Or it could be a draft mode for the FX-80.  The
  599. % situation is unclear.
  600. mode_def epsonlo =                      % Epson at 120dpi
  601.   EpsonMXFX_;
  602.   mode_param (pixels_per_inch, 120);
  603.   mode_param (aspect_ratio, 144 / pixels_per_inch);
  604. enddef;
  605. epslo := epsonlo;
  606.  
  607. % From {\tt drstrip@intvax.uucp}.
  608. mode_def GThreefax =                    % 200 x 100dpi G3fax
  609.   mode_param (pixels_per_inch, 200);
  610.   mode_param (aspect_ratio, 100 / pixels_per_inch);
  611.   mode_param (blacker, 0);
  612.   mode_param (fillin, .2);
  613.   mode_param (o_correction, .2);
  614.   mode_common_setup_;
  615. enddef;
  616.  
  617. % From {\tt fieberjr@whitman.bitnet}.
  618. mode_def HPDeskJet =                    % HP DeskJet 500
  619.   mode_param (pixels_per_inch, 300);
  620.   mode_param (blacker, 0);
  621.   mode_param (fillin, 0);
  622.   mode_param (o_correction, .6);
  623.   mode_common_setup_;
  624. enddef;
  625.  
  626. % Here are some general comments on the IBM printers, courtesy of {\tt
  627. % rocky@ibm.com}.
  628. % 
  629. % IBM 3820's, 3825's, 3827's and 3835's have some sort of corner imaging
  630. % or shading that the IBM 3812's and 3816's don't.  The latter two
  631. % models may get this feature in the future.
  632. %
  633. % The IBM 3827 is made by Kodak, the rest are IBM engines.
  634. %
  635. % Some of the other printers have a knob that allows a service engineer
  636. % to set one of up to ten levels of darkness.  At IBM Research, we run
  637. % very black.  The service engineer sets the level by running a
  638. % completely black page and then two completely blank ones. The black
  639. % page must be black and the following two must be completely white.
  640. %
  641. % Thanks to Jim Hafner ({\tt hafner@ibm.com}) for experimenting with
  642. % |blacker|, and Paul Dantzig for information about these printers.
  643.  
  644. % From {\tt rocky@ibm.com}.  For the typewriter, slanted, and
  645. % italic fonts, |blacker=0| makes the `M's and `W's more legible.  But
  646. % then the weight of the font does not match the others.
  647. mode_def IBMD =                         % IBM 38xx
  648.   mode_param (pixels_per_inch, 240);
  649.   mode_param (blacker, .3);
  650.   mode_param (fillin, .4);
  651.   mode_param (o_correction, .75);
  652.   mode_common_setup_;
  653. enddef;
  654.  
  655. % From {\tt vumalki\%weizmann.weizmann.ac.il@taunivm.tau.ac.il}.
  656. mode_def IBMFourTwoFiveZero =           % IBM 4250
  657.   mode_param (pixels_per_inch, 600);
  658.   mode_param (blacker, .05);
  659.   mode_param (fillin, 0);
  660.   mode_param (o_correction, .6);
  661.   mode_common_setup_;
  662. enddef;  
  663.  
  664. % From {\tt Martin.Ward@durham.ac.uk}.  Apparently the engine is
  665. % different from the Ricoh 4080.  With a larger value of |blacker|,
  666. % characters like the `e' in {\tt cmtt8} look bad.
  667. mode_def IBMFourTwoOneSix =             % IBM 4216
  668.   mode_param (pixels_per_inch, 300);
  669.   mode_param (blacker, .2);
  670.   mode_param (fillin, 0);
  671.   mode_param (o_correction, .75);
  672.   mode_common_setup_;
  673.   mode_write_white_setup_;
  674. enddef;
  675. RicohA := IBMFourTwoOneSix;
  676.  
  677. % From {\tt rocky@ibm.com}.  This is an old, untested definition.
  678. mode_def IBMSixSixSevenZero =           % IBM 6670 (Sherpa)
  679.   mode_param (pixels_per_inch, 240);
  680.   mode_param (blacker, 1);
  681.   mode_param (fillin, 1);
  682.   mode_param (o_correction, .5);
  683.   mode_common_setup_;
  684.   mode_write_white_setup_;
  685. enddef;
  686. Sherpa := IBMSixSixSevenZero;
  687.  
  688. % From {\tt vumalki\%weizmann.weizmann.ac.il@taunivm.tau.ac.il}.
  689. mode_def IBMThreeEightOneTwo =          % IBM 3812
  690.   mode_param (pixels_per_inch, 240);
  691.   mode_param (blacker, .6);
  692.   mode_param (fillin, .4);
  693.   mode_param (o_correction, 0);
  694.   mode_common_setup_;
  695.   mode_write_white_setup_;
  696. enddef;
  697. IBMUlfHolleberg := IBMThreeEightOneTwo;
  698.  
  699. % These values from {\tt d\_webb@chcc.harwell.aea-technology.uk}.
  700. mode_def IBMThreeEightTwoZero =         % IBM 3820
  701.   mode_param (pixels_per_inch, 240);
  702.   mode_param (blacker, .78);
  703.   mode_param (fillin, .25);
  704.   mode_param (o_correction, .5);
  705.   mode_common_setup_;
  706. enddef;
  707.  
  708. % These values from {\tt d\_webb@chcc.harwell.aea-technology.uk}.
  709. mode_def IBMVGA =                       % IBM VGA monitor
  710.   mode_param (pixels_per_inch, 110);
  711.   mode_param (blacker, .3);
  712.   mode_param (fillin, 0);
  713.   mode_param (o_correction, 0);
  714.   mode_common_setup_;
  715. enddef;
  716.  
  717. % Perhaps the value for |fillin| should be 0.
  718. mode_def imagewriter =                  % Apple ImageWriter
  719.   mode_param (pixels_per_inch, 144);
  720.   mode_param (blacker, 0);
  721.   mode_param (fillin, 0.3);
  722.   mode_param (o_correction, .2);
  723.   mode_common_setup_;
  724. enddef;
  725. iw := imagewriter;
  726.  
  727. % From {\tt ST-TeX.MF} via {\tt braams@pttrnl.nl}.  (The 300dpi LaserJet
  728. % is another |CanonCX|.)
  729. mode_def laserjetlo =                   % HP LaserJet at 150dpi
  730.   mode_param (pixels_per_inch, 150);
  731.   mode_param (blacker, 0);
  732.   mode_param (o_correction, 1);
  733.   mode_param (fillin, .1);
  734.   mode_common_setup_;
  735. enddef;
  736.  
  737. % From John Sauter.
  738. mode_def LASevenFive =                  % DEC LA75
  739.   mode_param (pixels_per_inch, 144);
  740.   mode_param (blacker, .3);
  741.   mode_param (fillin, -.1);
  742.   mode_param (o_correction, 0);
  743.   mode_common_setup_;
  744. enddef;
  745.  
  746. mode_def LinotypeOneZeroZeroLo =        % Linotype Linotronic [13]00 at 635dpi
  747.   LinotypeOneZeroZero_;
  748.   mode_param (pixels_per_inch, 635);
  749. enddef;
  750. linolo := LinotypeOneZeroZeroLo;
  751. linohalf := LinotypeOneZeroZeroLo;
  752.  
  753. % These values from {\tt d\_webb@chcc.harwell.aea-technology.uk}.  The
  754. % `a' in {\tt cmr5} looks better with |blacker=.3|.  Values of .2 for
  755. % both |blacker| and |fillin| have also been used.
  756. mode_def LinotypeOneZeroZero =          % Linotype Linotronic [13]00 at 1270dpi
  757.   mode_param (pixels_per_inch, 1270);
  758.   mode_param (blacker, .65);
  759.   mode_param (fillin, -.1);
  760.   mode_param (o_correction, .5);
  761.   mode_common_setup_;
  762.   mode_write_white_setup_;
  763. enddef;
  764. linoone := LinotypeOneZeroZero;
  765. linohi := LinotypeOneZeroZero;
  766. linothreelo := LinotypeOneZero;
  767.  
  768. % These values from {\tt d\_webb@chcc.harwell.aea-technology.uk}.
  769. mode_def LinotypeThreeZeroZeroHi =      % Linotype Linotronic 300 at 2540dpi
  770.   mode_param (pixels_per_inch, 2540);
  771.   mode_param (blacker, .2);                % Copied from |aps|---conjectural.
  772.   mode_param (fillin, .2);                 % (ditto)
  773.   mode_param (o_correction, 1);            % (ditto)
  774.   mode_common_setup_;
  775. enddef;
  776. linothree := LinotypeThreeZeroZero;
  777. linosuper := LinotypeThreeZeroZero;
  778.  
  779. % From Richard Watson at the Queensland Institute of Technology.  This
  780. % printer is said to have some kind of Xerox engine, but I don't know
  781. % which.
  782. mode_def LNZeroOne =                    % DEC LN01
  783.   mode_param (pixels_per_inch, 300);
  784.   mode_param (blacker, .9);
  785.   mode_param (fillin, 0);
  786.   mode_param (o_correction, .5);
  787.   mode_common_setup_;
  788. enddef;
  789.  
  790. % These values from {\tt karl@cs.umb.edu}.  |blacker = .8| or more
  791. % thickens dots, to their detriment.  |blacker = .6| produces two-pixel
  792. % stems, which looks pretty good for {\tt cmr}, but it's a little dark
  793. % for {\tt cmti}, and {\tt cmbx} and {\tt cmr} then turn out the same.
  794. % |o_correction = 1| made no difference.  |fillin = 1| made no
  795. % difference.
  796. mode_def lview =                        % Sigma L-View monitor
  797.   mode_param (pixels_per_inch, 118.06);
  798.   mode_param (aspect_ratio, 109.25 / pixels_per_inch);
  799.   mode_param (blacker, 0);
  800.   mode_param (fillin, 0);
  801.   mode_param (o_correction, 0);
  802.   mode_common_setup_;
  803. enddef;
  804.  
  805. % This |mode_def| is untested.
  806. mode_def MacMagnified =                 % Mac screens at magstep 1
  807.   mode_param (pixels_per_inch, 86.4);
  808.   mode_param (blacker, .35);
  809.   mode_param (fillin, .1);
  810.   mode_param (o_correction, .3);
  811.   mode_common_setup_;
  812. enddef;
  813. bettermac := MacMagnified;
  814.  
  815. % From the VMS distribution tape (except {\tt karl@cs.umb.edu} changed
  816. % the |o_correction| to zero).
  817. mode_def MacTrueSize =                  % Mac screens at 72dpi
  818.   mode_param (pixels_per_inch, 72);
  819.   mode_param (blacker, .0);
  820.   mode_param (fillin, 0);
  821.   mode_param (o_correction, 0);
  822.   mode_common_setup_;
  823. enddef;
  824. truemac := MacTrue;
  825.  
  826. % From {\tt rokicki@neon.stanford.edu}.
  827. mode_def NEC =                          % NEC
  828.   mode_param (pixels_per_inch, 180);
  829.   mode_param (blacker, 0);
  830.   mode_param (fillin, 0);
  831.   mode_param (o_correction, .2);
  832.   mode_common_setup_;
  833. enddef;
  834.  
  835. % This is the same as |CanonCX|, except for the resolution.
  836. mode_def NEChi =                        % NEC at 360dpi
  837.   CanonCX_;
  838.   mode_param (pixels_per_inch, 360);
  839. enddef;
  840.  
  841. % From {\tt lambert@silver.cs.umanitoba.ca}.
  842. mode_def Newgen =                       % Newgen 400dpi
  843.   CanonSX_;
  844.   mode_param (pixels_per_inch, 400);
  845. enddef;
  846.  
  847. % From {\tt rokicki@neon.stanford.edu}.
  848. mode_def NeXTprinter =                  % NeXT 400dpi
  849.   CanonCX_;
  850.   mode_param (pixels_per_inch, 400);
  851. enddef;
  852. nexthi := NeXTprinter;
  853.  
  854. % From {\tt rokicki@neon.stanford.edu}.
  855. mode_def NeXTscreen =                   % 100dpi NeXT monitor
  856.   mode_param (pixels_per_inch, 100);
  857.   mode_param (blacker, 0);
  858.   mode_param (fillin, 0);
  859.   mode_param (o_correction, 0);
  860.   mode_common_setup_;
  861. enddef;
  862. nextscreen := NeXTscreen;
  863.  
  864. % From {\tt deby@cs.utwente.nl}.
  865. mode_def OCESixSevenFiveZeroPS =        % OCE 6750PS
  866.   mode_param (pixels_per_inch, 508);
  867.   mode_param (blacker, 0);
  868.   mode_param (fillin, -.2);
  869.   mode_param (o_correction, .7);
  870.   mode_common_setup_;
  871. enddef;
  872.  
  873. % From {\tt rokicki@neon.stanford.edu}.
  874. mode_def okidata =                      % Okidata
  875.   mode_param (pixels_per_inch, 240);
  876.   mode_param (blacker, 0);
  877.   mode_param (fillin, 0);
  878.   mode_param (o_correction, .2);
  879.   mode_param (aspect_ratio, 288 / pixels_per_inch);
  880.   mode_common_setup_;
  881. enddef;
  882. okihi := okidata;
  883.  
  884. % {\tt AMSmodes.def} defines |pcscreen| to be essentially this, but with
  885. % a resolution of 118.  I figured |pcscreen| was such a general name
  886. % that I could change the definition slightly.
  887. mode_def OneTwoZero =                   % e.g., high-resolution Suns
  888.   mode_param (pixels_per_inch, 120);
  889.   mode_param (blacker, .35);
  890.   mode_param (fillin, .1);
  891.   mode_param (o_correction, .3);
  892.   mode_common_setup_;
  893. enddef;
  894. pcscreen := OneTwoZero;
  895.  
  896. % This is a write-white PostScript laser-setter, made by a Xerox
  897. % subsidiary.  It has a bizarre nonsquare resolution.  Headquarters in
  898. % Minnesota; telephone: (612) 456-1400.  At this resolution, the
  899. % write-white correction may not matter, but it is safer to turn it on
  900. % anyway.  This |mode_def| not yet tested in production.
  901. mode_def PrintwareSevenTwoZeroIQ =      % Printware 720IQ
  902.   mode_param (pixels_per_inch, 1200);
  903.   mode_param (aspect_ratio, 600 / pixels_per_inch);
  904.   mode_param (blacker, 0);
  905.   mode_param (fillin, 0);
  906.   mode_param (o_correction, 1);
  907.   mode_common_setup_;
  908.   mode_write_white_setup_;
  909. enddef;
  910.  
  911. % From John Gourlay.  See {\sl TUGboat} 8(2), page 133.
  912. mode_def qms =                          % QMS (Xerox engine)
  913.   mode_param (pixels_per_inch, 300);
  914.   mode_param (blacker, .6);
  915.   mode_param (fillin, -.3);
  916.   mode_param (o_correction, .6);
  917.   mode_common_setup_;
  918. enddef;
  919.  
  920. % These values from Stan Osborne, {\sl TUGboat} 8(2), page 134.
  921. mode_def RicohFourZeroEightZero =       % e.g., the TI Omnilaser
  922.   mode_param (pixels_per_inch, 300);
  923.   mode_param (blacker, .2);
  924.   mode_param (fillin, -.2);
  925.   mode_param (o_correction, .5);
  926.   mode_common_setup_;
  927.   mode_write_white_setup_;
  928. enddef;
  929. ricoh := RicohFourZeroEightZero;
  930. RicohFortyEighty := RicohFourZeroEightZero;
  931.  
  932. % From John Sauter.
  933. mode_def RicohLP =                      % e.g., the DEC LN03
  934.   mode_param (pixels_per_inch, 300);
  935.   mode_param (blacker, .65);
  936.   mode_param (fillin, -.2);
  937.   mode_param (o_correction, .5);
  938.   mode_common_setup_;
  939.   mode_write_white_setup_;
  940. enddef;
  941. LNOthree := RicohLP;
  942. LNZeroThree := RicohLP;
  943.  
  944. % From {\tt dickson@eeserv.ee.umanitoba.ca}.  {\tt gil.cc.gatech.edu}
  945. % has different values.
  946. mode_def SparcPrinter =                 % Sun SPARCprinter
  947.   mode_param (pixels_per_inch, 400);
  948.   mode_param (blacker, .2);
  949.   mode_param (fillin, .3);
  950.   mode_param (o_correction, 1);
  951.   mode_common_setup_;
  952. enddef;
  953.  
  954. % From {\tt ee@dacth51.bitnet}.
  955. mode_def StarNLOneZero =                % Star NL-10
  956.   mode_param (pixels_per_inch, 240);
  957.   mode_param (aspect_ratio, 216 / pixels_per_inch);
  958.   mode_param (blacker, -.6);
  959.   mode_param (fillin, .2);
  960.   mode_param (o_correction, .4);
  961.   mode_common_setup_;
  962. enddef;
  963.  
  964. % From {\tt grunwald@foobar.colorado.edu}.  Sun monitors have several
  965. % different resolutions, but this seems the best choice of the lot.
  966. mode_def sun =                          % Sun and BBN Bitgraph at 85dpi
  967.   mode_param (pixels_per_inch, 85);
  968.   mode_param (blacker, .35);
  969.   mode_param (fillin, .1);
  970.   mode_param (o_correction, .3);
  971.   mode_common_setup_;
  972.   enddef;
  973.  
  974. mode_def supre =                        % Ultre*setter at 2400dpi
  975.   mode_param (pixels_per_inch, 2400);
  976.   mode_param (blacker, 0);
  977.   mode_param (fillin, 0);
  978.   mode_param (o_correction, 1);
  979.   mode_common_setup_;
  980. enddef;
  981.  
  982. mode_def toshiba =                      % Toshiba 13XX, EpsonLQ
  983.   mode_param (pixels_per_inch, 180);
  984.   mode_param (blacker, 0);
  985.   mode_param (fillin, 0);
  986.   mode_param (o_correction, .2);
  987.   mode_common_setup_;
  988. enddef;
  989. epsonlq := toshiba;
  990.  
  991. mode_def ultre =                        % Ultre*setter at 1200dpi
  992.   mode_param (pixels_per_inch, 1200);
  993.   mode_param (blacker, 0);
  994.   mode_param (fillin, 0);
  995.   mode_param (o_correction, 1);
  996.   mode_common_setup_;
  997. enddef;
  998.  
  999. % From {\tt rocky@watson.ibm.com}.  This can also be used for the
  1000. % Autologic's APS6 cut sheet dry process printer.  For that printer,
  1001. % perhaps |blacker=0.8| is better. For the Varityper, though, at
  1002. % |blacker=0.8| the dots of the umlaut start to fill in.  For
  1003. % |blacker<0.6|, the tops and bottoms of lowercase g's and s's in {\tt
  1004. % cmr5} drop out.
  1005. mode_def VarityperFiveZeroSixZeroW =
  1006.   mode_param (pixels_per_inch, 600);
  1007.   mode_param (blacker, .7);
  1008.   mode_param (fillin, 0);
  1009.   mode_param (o_correction, 1);
  1010.   mode_common_setup_;
  1011. enddef;
  1012. APSSixMed := VarityperFiveZeroSixZeroW;
  1013.  
  1014. % The worst problem is toner irregularity.
  1015. mode_def VarityperSixZeroZero =         % Varityper Laser 600
  1016.   mode_param (pixels_per_inch, 600);
  1017.   mode_param (blacker, 0);
  1018.   mode_param (fillin, 0);
  1019.   mode_param (o_correction, 1);
  1020.   mode_common_setup_;
  1021. enddef;
  1022. varityper := VarityperSixZeroZero;
  1023. VTSix := VarityperSixZeroZero;
  1024.  
  1025. % From {\tt Martin.Ward@durham.ac.uk}.  
  1026. mode_def VAXstation =                   % VAXstation monitor
  1027.   mode_param (pixels_per_inch, 78);
  1028.   mode_param (blacker, 0);
  1029.   mode_param (fillin, 0);
  1030.   mode_param (o_correction, 0);
  1031.   mode_common_setup_;
  1032. enddef;
  1033. vs := VAXstation;
  1034. gpx := VAXstation;
  1035.  
  1036. % From {\tt u12570@uicvm.uic.edu}.  These values are mostly guesses.
  1037. mode_def XeroxEightSevenNineZero =      % Xerox 8790 or 4045
  1038.   mode_param (pixels_per_inch, 300);
  1039.   mode_param (blacker, 0.4);
  1040.   mode_param (fillin, 0);
  1041.   mode_param (o_correction, 0.2);
  1042.   mode_common_setup_;
  1043.   mode_write_white_setup_;
  1044. enddef;
  1045.  
  1046. % From {\tt u12570@uicvm.uic.edu}.  Many variations for different fonts
  1047. % here.
  1048. mode_def XeroxFourZeroFiveZero =        % Xerox 4050
  1049.   mode_param (pixels_per_inch, 300);
  1050.   mode_param (blacker, .7);
  1051.   mode_param (fillin, 0);
  1052.   mode_param (o_correction, .5);
  1053.   mode_common_setup_;
  1054. enddef;
  1055.  
  1056. % From {\tt u12570@uicvm.uic.edu}.  He sent many variations of this,
  1057. % for different fonts.  I don't know a reasonable way to put them in
  1058. % yet, so this is just the basic entry.
  1059. mode_def XeroxNineSevenZeroZero =       % Xerox 9700
  1060.   mode_param (pixels_per_inch, 300);
  1061.   mode_param (blacker, .7);
  1062.   mode_param (fillin, 0);
  1063.   mode_param (o_correction, .5);
  1064.   mode_common_setup_;
  1065. enddef;
  1066.  
  1067. % From {\tt lee@sq.com}.  These values may be improvable.
  1068. mode_def XeroxThreeSevenZeroZero =      % Xerox 3700
  1069.   mode_param (pixels_per_inch, 300);
  1070.   mode_param (blacker, .85);
  1071.   mode_param (fillin, -.1);
  1072.   mode_param (o_correction, .5);
  1073.   mode_common_setup_;
  1074.   mode_write_white_setup_;
  1075. enddef;
  1076.  
  1077. mode_def help =                         % What modes are defined?
  1078.  for i = 1 upto number_of_modes:
  1079.    message mode_name[i];
  1080.  endfor; 
  1081.  % Doesn't make sense to be able to do this twice, so forget this
  1082.  % definition after it's been used.
  1083.  save ?;
  1084. enddef;
  1085.  
  1086. let ? = help_;
  1087.  
  1088. % These variables determine the size of \MF's (window system) window for
  1089. % online output.  These numbers should match whatever the window system
  1090. % is told, or bizarre positioning of the output in the window results.
  1091. % Properly implemented online device drivers will use these values as
  1092. % the default size.
  1093. screen_cols := 400;
  1094. screen_rows := 600;
  1095.  
  1096. % The mode most commonly used to make fonts here.
  1097. localfont := CanonCX;
  1098.  
  1099. %%\bye
  1100. %%%% 
  1101. %%%% Local variables:
  1102. %%%% page-delimiter: "^% here are"
  1103. %%%% End:
  1104.